скиньте кто-нибудь ссылку как устанавливать какие либо параметры на индюки,на разные таймфреймы? заранее спасибо!)))

а я чет тут в попытке создать советник поюзал индюкатор ATR... шикарна штукенция для анализа тренд/коридор.. в смысле фильтра сигналов- работать по тренду или в коридоре (идеалов на рынкете конечно не бываеть, но в сочетании даже со стохастеГом ATR очень неплохо фильтрует ложные сигналы и сигналы коридорной и трендовой торговли)...выше некоторого уровня - тренд - ниже коридор.. для каждого инструмента и ТФ - свой уровень.. как гриться век живи век учись...
Это конечно ИМХа..
для евройены например на м15 если АTR (10) < 0.15 - ищем сигналы на отбой от границы канала  вбок (при стохастеге в зоне перекупленности/перепроданности), как тока АTR выше  0.15 ищем сигнал для входа в трендовое движение - с  подтверждением- например на пробой Лс..

для тех кто любит ма и уровни...

//+------------------------------------------------------------------+
//|                                                    StepMA_v7.mq4 |
//|                                Copyright © 2006, TrendLaboratory |
//|            http://finance.groups.yahoo.com/group/TrendLaboratory |
//|                                   E-mail: igorad2003@yahoo.co.uk |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2006, TrendLaboratory"
#property link      "http://finance.groups.yahoo.com/group/TrendLaboratory"

#property indicator_chart_window
#property indicator_buffers 3
#property indicator_color1 Aqua
#property indicator_color2 Blue
#property indicator_color3 Red

//---- input parameters
extern int     Length      = 10;      // Volty Length
extern double  Kv          = 1.0;     // Sensivity Factor
extern int     StepSize    = 0;       // Constant Step Size (if need)
extern int     MA_Mode     = 0;       // Volty MA Mode : 0-SMA, 1-LWMA
extern int     Advance     = 0;       // Offset
extern double  Percentage  = 0;       // Percentage of Up/Down Moving   
extern bool    HighLow     = false;   // High/Low Mode Switch (more sensitive)
extern int     ColorMode   = 0;       // Color Mode Switch
extern int     BarsNumber  = 0;       

//---- indicator buffers
double LineBuffer[];
double UpBuffer[];
double DnBuffer[];
double smin[];
double smax[];
double trend[];

double StepMA=0, ATR0=0,ATRmax=-100000,ATRmin=1000000;
int limit;

//---- StepSize Calculation

   double StepSizeCalc ( int Len, double Km, int Size, int k)
   {

   double result;
   if( Size==0 )
   {
        double AvgRange=0;
     for (int i=Len-1;i>=0;i--)
     {
            if(MA_Mode==0) double alfa= 1.0; else alfa= 1.0+1.0*(Len-i)/Len;
            AvgRange+= alfa*(High[k+i]-Low[k+i]);
        }
     ATR0 = AvgRange/Len;

if (ATR0>ATRmax) ATRmax=ATR0;
if (ATR0<ATRmin) ATRmin=ATR0;

result=MathRound(0.5*Km*(ATRmax+ATRmin)/Point);
}
else
result=Km*StepSize;
   
   return(result);
   }

//---- StepMA Calculation   
   
   double StepMACalc (bool HL, double Size, int k)
   {
   int counted_bars=IndicatorCounted();
   double result;
   
   if (HL)
  {
  smax[k]=Low[k]+2.0*Size*Point;
  smin[k]=High[k]-2.0*Size*Point;
     }
else 
  {
  smax[k]=Close[k]+2.0*Size*Point;
  smin[k]=Close[k]-2.0*Size*Point;
  }
  if (counted_bars==0){smax[limit+1]=smax[limit];smin[limit+1]=smin[limit];trend[limit+1]=0;}
 
  trend[k]=trend[k+1];   
 
  if (Close[k]>smax[k+1]) trend[k]=1;   

  if (Close[k]<smin[k+1]) trend[k]=-1; 

  if(trend[k]>0)
  {
  if(smin[k]<smin[k+1]) smin[k]=smin[k+1];
  result=smin[k]+Size*Point;
  }
  else
  {
  if(smax[k]>smax[k+1]) smax[k]=smax[k+1];
  result=smax[k]-Size*Point;
  }
     //Print (" k=",k," trend=",trend[k], " res=",result," Smax=", smax[k], " Smin=", smin[k]);
 
     
     return(result);
     }
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
  int init()
  {
   string short_name;
//---- indicator line
   IndicatorBuffers(6);
   
   SetIndexStyle(0,DRAW_LINE,STYLE_SOLID,2);
   SetIndexStyle(1,DRAW_LINE);
   SetIndexStyle(2,DRAW_LINE);
   
   SetIndexArrow(1,159);
   SetIndexArrow(2,159);
   
   SetIndexBuffer(0,LineBuffer);
   SetIndexBuffer(1,UpBuffer);
   SetIndexBuffer(2,DnBuffer);
   
   SetIndexShift(0,Advance);
   SetIndexShift(1,Advance);
   SetIndexShift(2,Advance);
   
   SetIndexBuffer(3,smin);
   SetIndexBuffer(4,smax);
   SetIndexBuffer(5,trend);
   
//---- name for DataWindow and indicator subwindow label
   short_name="StepMA("+Length+","+Kv+","+StepSize+")";
   IndicatorShortName(short_name);
   SetIndexLabel(0,short_name);
   SetIndexLabel(1,"UpTrend");
   SetIndexLabel(2,"DownTrend");
//----
   SetIndexDrawBegin(0,Length);
   SetIndexDrawBegin(1,Length);
   SetIndexDrawBegin(2,Length);
//----
   return(0);
   }
//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//----
   
//----
   return(0);
  }     
//+------------------------------------------------------------------+
//| StepMA_v7                                                        |
//+------------------------------------------------------------------+
int start()
  {
   int shift, counted_bars=IndicatorCounted();
     
   if ( BarsNumber > 0 ) int Nbars=BarsNumber; else Nbars=Bars;
   if ( counted_bars > 0 )  limit=Nbars-counted_bars;
   if ( counted_bars < 0 )  return(0);
   if ( counted_bars ==0 )  limit=Nbars-Length-1;
     
for(shift=limit;shift>=0;shift--)
   {
     
int Step = StepSizeCalc( Length, Kv, StepSize, shift);
       
Comment (" StepSize= ", Step);

StepMA = StepMACalc ( HighLow, Step, shift)+Percentage/100.0*Step*Point;

if ( ColorMode == 0) LineBuffer[shift]=StepMA;

if ( ColorMode == 1)
{
if ( trend[shift]>0 ) {UpBuffer[shift]=StepMA-Step*Point;DnBuffer[shift]=EMPTY_VALUE;}
else
if ( trend[shift]<0 ) {DnBuffer[shift]=StepMA+Step*Point;UpBuffer[shift]=EMPTY_VALUE;}
}
else
if ( ColorMode == 2)
{
if (trend[shift]>0)
  {
  UpBuffer[shift]=StepMA;
  if ( trend[shift+1] < 0 ) UpBuffer[shift+1] = DnBuffer[shift+1];
  DnBuffer[shift]=EMPTY_VALUE;
  }
  if (trend[shift]<0)
  {
  DnBuffer[shift]=StepMA;
  if ( trend[shift+1] > 0 ) DnBuffer[shift+1] = UpBuffer[shift+1];
  UpBuffer[shift]=EMPTY_VALUE;
  }
}
else
{
UpBuffer[shift]=EMPTY_VALUE; DnBuffer[shift]=EMPTY_VALUE;
}

}
return(0);
}

//+------------------------------------------------------------------+
//|                                    Waddah Attar Dayly CAMARRILLA |
//|                               Copyright © 2007, ww.metaforex.net |
//|                                   Waddah Attar wwwmetaforex.net |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2007, wwwmetaforex.net"
#property link      "www.metaforex.net"
//----
#property indicator_chart_window
#property indicator_buffers 8
#property indicator_color1 Green
#property indicator_color2 Red
#property indicator_color3 Green
#property indicator_color4 Red
#property indicator_color5 Green
#property indicator_color6 Red
#property indicator_color7 Green
#property indicator_color8 Red

//---- buffers
double P1Buffer[];
double P2Buffer[];
double P3Buffer[];
double P4Buffer[];
double P5Buffer[];
double P6Buffer[];
double P7Buffer[];
double P8Buffer[];
//----
int myPeriod = PERIOD_D1;
//----
double H1, L1, H2, L2, H3, L3, H4, L4, Q;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   SetIndexBuffer(0, P1Buffer);
   SetIndexBuffer(1, P2Buffer);
   SetIndexBuffer(2, P3Buffer);
   SetIndexBuffer(3, P4Buffer);
   SetIndexBuffer(4, P5Buffer);
   SetIndexBuffer(5, P6Buffer);
   SetIndexBuffer(6, P7Buffer);
   SetIndexBuffer(7, P8Buffer);
//----
   SetIndexStyle(0, DRAW_LINE, STYLE_SOLID, 1);
   SetIndexStyle(1, DRAW_LINE, STYLE_SOLID, 1);
   SetIndexStyle(2, DRAW_LINE, STYLE_SOLID, 1);
   SetIndexStyle(3, DRAW_LINE, STYLE_SOLID, 1);
   SetIndexStyle(4, DRAW_LINE, STYLE_SOLID, 1);
   SetIndexStyle(5, DRAW_LINE, STYLE_SOLID, 1);
   SetIndexStyle(6, DRAW_LINE, STYLE_SOLID, 1);
   SetIndexStyle(7, DRAW_LINE, STYLE_SOLID, 1);
//----
   Comment("Dayly CAMARRILLA By eng.Waddah Attar  wwwmetaforex.net");
   return(0);
  }
//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
   ObjectDelete("DayH1");
   ObjectDelete("DayH2");
   ObjectDelete("DayH3");
   ObjectDelete("DayH4");

   ObjectDelete("DayL1");
   ObjectDelete("DayL2");
   ObjectDelete("DayL3");
   ObjectDelete("DayL4");

   ObjectDelete("txtDayH1");
   ObjectDelete("txtDayH2");
   ObjectDelete("txtDayH3");
   ObjectDelete("txtDayH4");

   ObjectDelete("txtDayL1");
   ObjectDelete("txtDayL2");
   ObjectDelete("txtDayL3");
   ObjectDelete("txtDayL4");
   Comment("");
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   int i, dayi, counted_bars = IndicatorCounted();
//---- check for possible errors
   if(counted_bars < 0)
       return(-1);
//---- last counted bar will be recounted
   if(counted_bars > 0)
       counted_bars--; 
   int limit = Bars - counted_bars;
//----   
   for(i = limit - 1; i >= 0; i--)
     {
       dayi = iBarShift(Symbol(), myPeriod, Time[i], false);
       Q = (iHigh(Symbol(), myPeriod,dayi+1) - iLow(Symbol(), myPeriod,
            dayi + 1));
       //----
       H1 = iClose(Symbol(), myPeriod,dayi+1) + (Q * 0.09);
       L1 = iClose(Symbol(), myPeriod,dayi+1) - (Q * 0.09);
       //----
       H2 = iClose(Symbol(), myPeriod,dayi+1) + (Q * 0.18);
       L2 = iClose(Symbol(), myPeriod,dayi+1) - (Q * 0.18);
       //----
       H3 = iClose(Symbol(), myPeriod,dayi+1) + (Q * 0.27);
       L3 = iClose(Symbol(), myPeriod,dayi+1) - (Q * 0.27);
       //----
       H4 = iClose(Symbol(), myPeriod,dayi+1) + (Q * 0.55);
       L4 = iClose(Symbol(), myPeriod,dayi+1) - (Q * 0.55);
       //----
       P1Buffer[i] = H1;
       SetPrice("DayH1", Time[i], H1, Green);
       SetText("txtDayH1", "H1", Time[i], H1, Green);
       //----
       P2Buffer[i] = L1;
       SetPrice("DayL1", Time[i], L1, Red);
       SetText("txtDayL1", "L1", Time[i], L1, Red);
       //----
       P3Buffer[i] = H2;
       SetPrice("DayH2", Time[i], H2, Green);
       SetText("txtDayH2", "H2", Time[i], H2, Green);
       //----
       P4Buffer[i] = L2;
       SetPrice("DayL2",Time[i],L2,Red);
       SetText("txtDayL2","L2",Time[i],L2,Red);
       //----
       P5Buffer[i] = H3;
       SetPrice("DayH3", Time[i], H3, Green);
       SetText("txtDayH3", "H3", Time[i], H3, Green);
       //----
       P6Buffer[i] = L3;
       SetPrice("DayL3", Time[i], L3, Red);
       SetText("txtDayL3", "L3", Time[i], L3, Red);
       //----
       P7Buffer[i] = H4;
       SetPrice("DayH4", Time[i], H4, Green);
       SetText("txtDayH4", "H4", Time[i], H4, Green);
       //----
       P8Buffer[i] = L4;
       SetPrice("DayL4", Time[i], L4, Red);
       SetText("txtDayL4", "L4", Time[i], L4, Red);

    }
//----
   return(0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void SetPrice(string name, datetime Tm, double Prc, color clr)
  {
   if(ObjectFind(name) == -1)
     {
       ObjectCreate(name, OBJ_ARROW, 0, Tm, Prc);
       ObjectSet(name, OBJPROP_COLOR, clr);
       ObjectSet(name, OBJPROP_WIDTH, 1);
       ObjectSet(name, OBJPROP_ARROWCODE, SYMBOL_RIGHTPRICE);
     }
   else
     {
       ObjectSet(name, OBJPROP_TIME1, Tm);
       ObjectSet(name, OBJPROP_PRICE1, Prc);
       ObjectSet(name, OBJPROP_COLOR, clr);
       ObjectSet(name, OBJPROP_WIDTH, 1);
       ObjectSet(name, OBJPROP_ARROWCODE, SYMBOL_RIGHTPRICE);
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void SetText(string name, string txt, datetime Tm, double Prc, color clr)
  {
   if(ObjectFind(name) == -1)
     {
       ObjectCreate(name, OBJ_TEXT, 0, Tm, Prc);
       ObjectSetText(name, txt, 10, "Times New Roman", clr);
       ObjectSet(name, OBJPROP_CORNER, 2);
     }
   else
     {
       ObjectSet(name, OBJPROP_TIME1, Tm);
       ObjectSet(name, OBJPROP_PRICE1, Prc);
       ObjectSetText(name, txt, 10, "Times New Roman", clr);
       ObjectSet(name, OBJPROP_CORNER, 2);
     }
  }
//+------------------------------------------------------------------+